A better vehicle/simulations control thru the keyboard

First of all, we need to understand why controlling the vehicle thru the keyboard doesn't work :

problem 1) When you bind a key to a function using the moveMap.bind command ie.

moveMap.bind( keyboard, a, moveleft );

function moveleft(%val)
{
   $mvLeftAction = %val * $movementSpeed;
}

the function will be called once when the key is pressed ( in this case the "a" key ) setting %val as 1 and once when the key is depressed setting %val as 0.

This is the equivalent of steering the wheel all the way left as soon as you press the "a" key. This is not what you expect a simulator to do. Simulators increment the steering value while the key is pressed. If you press it for longer, you will steer the whell further right than if you press it shortly.

the same doesn't happen when you use the mouse because the mouse displacement is used to calculate the ammount of steering you need.

Problem 2) The same happens with the acceleration/brake mechanism. When you press the forward key you pump all the gas and when you release it you take your foot off the acelerator.

Problem 2 is actually easier to deal with, first check out this resource by Alex "Bathala" Rufon. It will explain how to move your character forward without pressing a key. Next just type in the following code in your default.bind.cs module ( usually in your game's client folder ) :

function incmove(%val)
{
   $movementSpeed += 0.1;
   if($movementSpeed > 1.0 ) 
      $movementSpeed = 1.0;
 $mvForwardAction = $movementSpeed;
}

function decmove(%val)
{
   $movementSpeed -= 0.1;
   if($movementSpeed < 0.1 ) 
      $movementSpeed = 0.1;
 $mvForwardAction = $movementSpeed;
}

moveMap.bind(keyboard, p, incMove);
moveMap.bind(keyboard, o, decMove);

This code snippet will acellerate/brake you by incrementing/decrementing the global $movementSpeed variable. Since I'm doing a flight sim, I don't want my planes to stop in mid air so there is an if to clamp the value at 0.1 but you could change it to 0 as well.
Now you should be able to control the throttle in a more gentle way thru the "p" and "o" keys.

OK, now that Problem 2 is solved, let's take care of Problem 1. This is a more complex task. Since I don't know for how long the key is preesed, what I need to do is spawn ( schedule ) a thread that will continuasly incremennt my value until told otherwise.

function yawLeft(%val)
{
	if(%val)
           $incYawId = schedule(100,0,"incYaw",-1);
        else
        {
           cancel($incYawId);  
           $mvYaw = 0;
        }    
 }

If %val is 1 ( the key is pressed ), then the "incYaw" function will be scheduled to run in the next 100 miliseconds with the value "-1" ( left) as a parameter. The thread number of incYaw will be stored in the global $incYawId. we need to store it in a global because this value will be changed by the IncYaw function.
If %val is 0 then the incYaw function will be cancelled and $mvYaw will be set to 0;

function incYaw(%val)
{
    $mvYaw += %val;
   $incYawid = schedule(100,0,"incYaw",%val);
}

When incYaw is executed, it will update $mvYaw AND schedule itself to run again in 100 miliseconds. Note that $incYawId will receive a new value here, the value of the next scheduled incYaw function. This value will be needed by the yawLeft function that will cancel the next incYaw that will be executed and not the incYaw that it spawned.

Next, all you need to do is add a keyboard binding for yawLeft, create a YawRight - note that you don't have to create a new incYaw function, just pass 1 as the parameter in YawRight instead of the "-1" parameter of YawLeft. And replicate this structure for pitch.
And, since I've done it before, here goes the complete code :

function yawLeft(%val)
{
	if(%val)
           $incYawid = schedule(100,0,"incYaw",-1);
        else
        {
           cancel($incYawid);  
           $mvYaw = 0;
        }    
 }

function yawRight(%val)
{
	if(%val)
           $incYawid = schedule(100,0,"incYaw",1);
        else
        {
           cancel($incYawid);  
           $mvYaw = 0;
        }    
}

function incYaw(%val)
{
    $mvYaw += %val;
   $incYawid = schedule(100,0,"incYaw",%val);
}


function pitchUp(%val)
{
	if(%val)
           $incPitchId = schedule(100,0,"incPitch",-1);
        else
        {
           cancel($incPitchId);  
           $mvPitch = 0;
        }    
}

function pitchDown(%val)
{
	if(%val)
           $incPitchId = schedule(100,0,"incPitch",1);
        else
        {
           cancel($incPitchId);  
           $mvPitch = 0;
        }    
}

function incPitch(%val)
{
     $mvPitch += %val;
   $incPitchId = schedule(100,0,"incPitch",%val);
}

moveMap.bind( keyboard, up, pitchDown );
moveMap.bind( keyboard, down, pitchUp);
moveMap.bind( keyboard, left, yawLeft );
moveMap.bind( keyboard, right, yawRight );

Note that I'm using a FlySim convention here, down key means pulling the stick towards you, hence going up.

Enjoy !!